SWAMPy

✎ CARVE FLESH

EDITING: experimental.pm

package experimental;
$experimental::VERSION = '0.022';
use strict;
use warnings;
use version ();

BEGIN { eval { require feature } };
use Carp qw/croak carp/;

my %warnings = map { $_ => 1 } grep { /^experimental::/ } keys %warnings::Offsets;
my %features = map { $_ => 1 } $] > 5.015006 ? keys %feature::feature : do {
	my @features;
	if ($] >= 5.010) {
		push @features, qw/switch say state/;
		push @features, 'unicode_strings' if $] > 5.011002;
	}
	@features;
};

my %min_version = (
	array_base      => '5',
	autoderef       => '5.14.0',
	bitwise         => '5.22.0',
	const_attr      => '5.22.0',
	current_sub     => '5.16.0',
	declared_refs   => '5.26.0',
	evalbytes       => '5.16.0',
	fc              => '5.16.0',
	isa             => '5.31.7',
	lexical_topic   => '5.10.0',
	lexical_subs    => '5.18.0',
	postderef       => '5.20.0',
	postderef_qq    => '5.20.0',
	refaliasing     => '5.22.0',
	regex_sets      => '5.18.0',
	say             => '5.10.0',
	smartmatch      => '5.10.0',
	signatures      => '5.20.0',
	state           => '5.10.0',
	switch          => '5.10.0',
	unicode_eval    => '5.16.0',
	unicode_strings => '5.12.0',
);
my %removed_in_version = (
	array_base      => '5.29.4',
	autoderef       => '5.23.1',
	lexical_topic   => '5.23.4',
);

$_ = version->new($_) for values %min_version;
$_ = version->new($_) for values %removed_in_version;

my %additional = (
	postderef     => ['postderef_qq'],
	switch        => ['smartmatch'],
	declared_refs => ['refaliasing'],
);

sub _enable {
	my $pragma = shift;
	if ($warnings{"experimental::$pragma"}) {
		warnings->unimport("experimental::$pragma");
		feature->import($pragma) if exists $features{$pragma};
		_enable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif ($features{$pragma}) {
		feature->import($pragma);
		_enable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif (not exists $min_version{$pragma}) {
		croak "Can't enable unknown feature $pragma";
	}
	elsif ($] < $min_version{$pragma}) {
		my $stable = $min_version{$pragma};
		if ($stable->{version}[1] % 2) {
			$stable = version->new(
				"5.".($stable->{version}[1]+1).'.0'
			);
		}
		croak "Need perl $stable or later for feature $pragma";
	}
	elsif ($] >= ($removed_in_version{$pragma} || 7)) {
		croak "Experimental feature $pragma has been removed from perl in version $removed_in_version{$pragma}";
	}
}

sub import {
	my ($self, @pragmas) = @_;

for my $pragma (@pragmas) {
		_enable($pragma);
	}
	return;
}

sub _disable {
	my $pragma = shift;
	if ($warnings{"experimental::$pragma"}) {
		warnings->import("experimental::$pragma");
		feature->unimport($pragma) if exists $features{$pragma};
		_disable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif ($features{$pragma}) {
		feature->unimport($pragma);
		_disable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif (not exists $min_version{$pragma}) {
		carp "Can't disable unknown feature $pragma, ignoring";
	}
}

sub unimport {
	my ($self, @pragmas) = @_;

for my $pragma (@pragmas) {
		_disable($pragma);
	}
	return;
}

#ABSTRACT: Experimental features made easy

__END__

=pod

=encoding UTF-8

=head1 NAME

experimental - Experimental features made easy

=head1 VERSION

version 0.022

=head1 SYNOPSIS

use experimental 'lexical_subs', 'smartmatch';
 my sub foo { $_[0] ~~ 1 }

=head1 DESCRIPTION

This pragma provides an easy and convenient way to enable or disable
experimental features.

Every version of perl has some number of features present but considered
"experimental."  For much of the life of Perl 5, this was only a designation
found in the documentation.  Starting in Perl v5.10.0, and more aggressively in
v5.18.0, experimental features were placed behind pragmata used to enable the
feature and disable associated warnings.

The C<experimental> pragma exists to combine the required incantations into a
single interface stable across releases of perl.  For every experimental
feature, this should enable the feature and silence warnings for the enclosing
lexical scope:

use experimental 'feature-name';

To disable the feature and, if applicable, re-enable any warnings, use:

no experimental 'feature-name';

The supported features, documented further below, are:

=over 4

=item * C<array_base> - allow the use of C<$[> to change the starting index of C<@array>.

This is supported on all versions of perl.

=item * C<autoderef> - allow push, each, keys, and other built-ins on references.

This was added in perl 5.14.0 and removed in perl 5.23.1.

=item * C<bitwise> - allow the new stringwise bit operators

This was added in perl 5.22.0.

=item * C<const_attr> - allow the :const attribute on subs

This was added in perl 5.22.0.

=item * C<declared_refs> - enables aliasing via assignment to references

This was added in perl 5.26.0.

=item * C<isa> - allow the use of the C<isa> infix operator

This was added in perl 5.32.0.

=item * C<lexical_topic> - allow the use of lexical C<$_> via C<my $_>.

This was added in perl 5.10.0 and removed in perl 5.23.4.

=item * C<lexical_subs> - allow the use of lexical subroutines.

This was added in 5.18.0.

=item * C<postderef> - allow the use of postfix dereferencing expressions

This was added in perl 5.20.0, and became non-experimental (and always enabled) in 5.24.0.

=item * C<postderef_qq> - allow the use of postfix dereferencing expressions inside interpolating strings

This was added in perl 5.20.0, and became non-experimental (and always enabled) in 5.24.0.

=item * C<re_strict> - enables strict mode in regular expressions

This was added in perl 5.22.0.

=item * C<refaliasing> - allow aliasing via C<\$x = \$y>

This was added in perl 5.22.0.

=item * C<regex_sets> - allow extended bracketed character classes in regexps

This was added in perl 5.18.0.

=item * C<signatures> - allow subroutine signatures (for named arguments)

This was added in perl 5.20.0.

=item * C<smartmatch> - allow the use of C<~~>

This was added in perl 5.10.0, but it should be noted there are significant
incompatibilities between 5.10.0 and 5.10.1.

=item * C<switch> - allow the use of C<~~>, given, and when

This was added in perl 5.10.0.

=item * C<win32_perlio> - allows the use of the :win32 IO layer.

This was added on perl 5.22.0.

=back

=head2 Ordering matters

Using this pragma to 'enable an experimental feature' is another way of saying
that this pragma will disable the warnings which would result from using that
feature.  Therefore, the order in which pragmas are applied is important.  In
particular, you probably want to enable experimental features I<after> you
enable warnings:

use warnings;
  use experimental 'smartmatch';

You also need to take care with modules that enable warnings for you.  A common
example being Moose.  In this example, warnings for the 'smartmatch' feature are
first turned on by the warnings pragma, off by the experimental pragma and back
on again by the Moose module (fix is to switch the last two lines):

use warnings;
  use experimental 'smartmatch';
  use Moose;

=head2 Disclaimer

Because of the nature of the features it enables, forward compatibility can not
be guaranteed in any way.

=head1 SEE ALSO

L<perlexperiment|perlexperiment> contains more information about experimental features.

=head1 AUTHOR

Leon Timmermans <leont@cpan.org>

=head1 COPYRIGHT AND LICENSE

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut

CANCEL

Name	Type	Size	Modified	Actions
↩ ..	DIR	—	—
📁 Algorithm/	DIR	—	2024-02-20 03:37
📁 App/	DIR	—	2025-05-21 19:16
📁 Archive/	DIR	—	2024-02-20 03:37
📁 Authen/	DIR	—	2024-02-20 03:45
📁 autodie/	DIR	—	2024-02-20 03:37
📁 Carp/	DIR	—	2024-02-20 03:37
📁 Config/	DIR	—	2024-02-20 03:37
📁 CPAN/	DIR	—	2025-05-21 19:16
📁 Data/	DIR	—	2024-02-20 03:45
📁 Date/	DIR	—	2024-02-20 03:45
📁 Digest/	DIR	—	2024-02-20 03:45
📁 Encode/	DIR	—	2024-02-20 03:37
📁 Error/	DIR	—	2024-02-21 10:59
📁 Exporter/	DIR	—	2024-02-20 03:37
📁 ExtUtils/	DIR	—	2024-02-20 03:37
📁 File/	DIR	—	2024-02-20 03:45
📁 Filter/	DIR	—	2024-02-20 03:37
📁 Getopt/	DIR	—	2024-02-20 03:37
📁 Git/	DIR	—	2025-07-30 00:12
📁 HTML/	DIR	—	2024-02-20 03:45
📁 HTTP/	DIR	—	2024-05-10 15:37
📁 inc/	DIR	—	2024-02-20 03:37
📁 IO/	DIR	—	2024-10-03 04:48
📁 IPC/	DIR	—	2024-02-20 03:37
📁 JSON/	DIR	—	2024-02-20 03:37
📁 lib/	DIR	—	2024-02-20 03:37
📁 libwww/	DIR	—	2024-02-20 03:45
📁 local/	DIR	—	2024-02-20 03:37
📁 Locale/	DIR	—	2024-02-20 03:37
📁 LWP/	DIR	—	2024-02-20 03:45
📁 Math/	DIR	—	2024-02-20 03:37
📁 MIME/	DIR	—	2024-02-20 03:37
📁 Module/	DIR	—	2025-05-21 19:15
📁 Mozilla/	DIR	—	2024-02-20 03:37
📁 MRO/	DIR	—	2024-02-20 03:37
📁 Net/	DIR	—	2024-02-20 03:45
📁 Object/	DIR	—	2024-02-20 03:37
📁 Package/	DIR	—	2024-02-20 03:37
📁 Params/	DIR	—	2024-02-20 03:37
📁 Parse/	DIR	—	2024-02-20 03:37
📁 Perl/	DIR	—	2024-02-20 03:37
📁 PerlIO/	DIR	—	2024-02-20 03:37
📁 Pod/	DIR	—	2024-02-20 03:37
📁 POD2/	DIR	—	2024-02-20 03:37
📁 Software/	DIR	—	2024-02-20 03:37
📁 Sub/	DIR	—	2024-02-20 03:37
📁 TAP/	DIR	—	2024-02-20 03:37
📁 Term/	DIR	—	2024-02-20 03:37
📁 Test/	DIR	—	2024-02-20 03:37
📁 Test2/	DIR	—	2024-02-20 03:37
📁 Text/	DIR	—	2024-02-20 03:37
📁 Thread/	DIR	—	2024-02-20 03:37
📁 Tie/	DIR	—	2024-02-20 03:37
📁 Time/	DIR	—	2024-02-20 03:45
📁 Try/	DIR	—	2024-02-20 03:45
📁 Types/	DIR	—	2024-02-20 03:45
📁 WWW/	DIR	—	2024-02-20 03:45
📄 autodie.pm	PM	12.1 KB	2021-01-22 17:03	EDIT
📄 bigint.pm	PM	22.8 KB	2018-10-09 16:55	EDIT
📄 bignum.pm	PM	20.6 KB	2018-10-09 16:55	EDIT
📄 bigrat.pm	PM	15.8 KB	2018-10-09 16:55	EDIT
📄 Carp.pm	PM	35.1 KB	2018-06-27 11:17	EDIT
📄 constant.pm	PM	14.4 KB	2022-02-16 13:19	EDIT
📄 CPAN.pm	PM	144.4 KB	2025-05-13 21:00	EDIT
📄 Digest.pm	PM	11 KB	2020-10-13 19:59	EDIT
📄 Env.pm	PM	5.4 KB	2013-03-02 17:10	EDIT
📄 Error.pm	PM	29.4 KB	2020-01-28 16:51	EDIT
📄 Expect.pm	PM	98.1 KB	2017-05-18 19:07	EDIT
📄 experimental.pm	PM	7.4 KB	2020-05-04 20:34	EDIT
📄 Exporter.pm	PM	18.4 KB	2019-11-18 22:21	EDIT
📄 Fatal.pm	PM	57.7 KB	2021-01-22 17:03	EDIT
📄 Git.pm	PM	46.9 KB	2025-07-21 16:27	EDIT
📄 Importer.pm	PM	41.5 KB	2020-08-16 21:24	EDIT
📄 LWP.pm	PM	21.2 KB	2021-03-07 16:54	EDIT
📄 newgetopt.pl	PL	2.2 KB	2010-07-09 12:26	EDIT
📄 ok.pm	PM	967 B	2020-10-22 03:10	EDIT
📄 parent.pm	PM	2.6 KB	2020-02-07 07:43	EDIT
📄 perldoc.pod	POD	9.2 KB	2016-08-02 16:31	EDIT
📄 perlfaq.pm	PM	77 B	2021-05-20 04:16	EDIT
📄 perlfaq.pod	POD	22.3 KB	2021-05-20 04:16	EDIT
📄 perlfaq1.pod	POD	14.1 KB	2021-05-20 04:16	EDIT
📄 perlfaq2.pod	POD	9.2 KB	2021-05-20 04:16	EDIT
📄 perlfaq3.pod	POD	36.7 KB	2021-05-20 04:16	EDIT
📄 perlfaq4.pod	POD	88.7 KB	2021-05-20 04:16	EDIT
📄 perlfaq5.pod	POD	54 KB	2021-05-20 04:16	EDIT
📄 perlfaq6.pod	POD	38.6 KB	2021-05-20 04:16	EDIT
📄 perlfaq7.pod	POD	36.9 KB	2021-05-20 04:16	EDIT
📄 perlfaq8.pod	POD	48.8 KB	2021-05-20 04:16	EDIT
📄 perlfaq9.pod	POD	14.9 KB	2021-05-20 04:16	EDIT
📄 perlglossary.pod	POD	134 KB	2021-05-20 04:16	EDIT
📄 perlxs.pod	POD	82.3 KB	2022-02-16 08:56	EDIT
📄 perlxstut.pod	POD	48.9 KB	2022-02-16 08:56	EDIT
📄 perlxstypemap.pod	POD	23.4 KB	2022-02-16 08:56	EDIT
📄 Test2.pm	PM	6.2 KB	2020-10-22 03:10	EDIT
📄 TimeDate.pm	PM	267 B	2020-05-19 17:30	EDIT